Excel函数公式都不常用，但一旦遇到就会让你感觉头痛，只能到处提问和查找。今天兰色把这些公式收集到一起。以备急时之需。

1、生成不重复随机数公式

B2:(数组公式，按ctrl+shift+enter三键输入)

=SMALL(IF(COUNTIF(B$1:B1,ROW($1:$10)),"",ROW($1:$10)),RANDBETWEEN(1,10-COUNT(B$1:B1)))

2、多区域排名公式

=RANK(B3,($B$3:$B$10,$E$3:$E$10,$H$3:$H$10))

3、提取唯一值公式

C2(数组公式按ctrl+shift+enter三键输入)

=IFERROR(INDEX(A:A,SMALL(IF(MATCH(A$2:A$9,A$2:A$9,)=ROW($1:$8),ROW($2:$9)),ROW(A1))),"")

有一个简单的

=INDEX(A:A,MATCH(0,COUNTIF(C$1:C1,A$1:A$99),0))&""

office365更简单：

=UNIQUE(A1:A9)

4、多区域超链接公式

=HYPERLINK("#C3:C10,F3:F10,I3:I10","总排名")

5、提取筛选后的内容

公式：（数组公式，按ctrl+shift+enter三键输入）

=INDEX(B:B,MATCH(1,SUBTOTAL(3,OFFSET(B1,ROW(1:100),)),0)+1)

6、字符串拆分

B2

=TRIM(MID(SUBSTITUTE($A2,"-",REPT(" ",99)),99*COLUMN(A1)-98,99))

7、动态获取A列最后一个数字

=LOOKUP(1,0/(A2:A100>0),A2:A100)

8、不重复个数公式

=SUMPRODUCT(1/COUNTIF(A2:A7,A2:A7))

9、中国式排名公式

=SUMPRODUCT(($D$4:$D$9>=D4)*(1/COUNTIF(D$4:D$9,D$4:D$9)))

10、提取字符串任一位中的数字

A1的值为 ABC123.45FE ,截取结果：123.45

数组公式：{=LOOKUP(9^9,MID(A1,MATCH(1,MID(A1,ROW(1:9),1)^0,0),ROW(1:9))*1)}

11、金额大写转换公式

=TEXT(LEFT(RMB(A2),LEN(RMB(A2))-3),"[>0][dbnum2]G/通用格式元;[<0]负[dbnum2]G/通用格式元;;") & TEXT(RIGHT(RMB(A2),2),"[dbnum2]0角0分;;整")

12、一对多查找包含公式

=COUNT(FIND({"AAA花苑","CCC龙廷"},A2))

13、Vlookup多表查找公式

工资表模板中，每个部门一个表。

在查询表中，要求根据提供的姓名，从销售~综合5个工作表中查询该员工的基本工资。

方法1：

=IFERROR(VLOOKUP(A2,服务!A:G,7,0),IFERROR(VLOOKUP(A2,人事!A:G,7,0),IFERROR(VLOOKUP(A2,综合!A:G,7,0),IFERROR(VLOOKUP(A2,财务!A:G,7,0),IFERROR(VLOOKUP(A2,销售!A:G,7,0),"无此人信息")))))

方法2

=VLOOKUP(A2,INDIRECT(LOOKUP(1,0/COUNTIF(INDIRECT({"销售";"服务";"人事";"综合";"财务"}&"!a:a"),A2),{"销售";"服务";"人事";"综合";"财务"})&"!a:g"),7,0)

14、Sumif多表求和公式

工作表名称常常是不规则的，如下图所示

分析：

首先我们需要用宏表函数取得表名

公式 - 名称管理器 - 新建名称 - 在新建名称中输入名称“sh”，然后“引用位置”框中输入公式：

=MID(GET.WORKBOOK(1),FIND("]",GET.WORKBOOK(1))+1,99)&T(now())

最终公式为：

=SUMPRODUCT((SUMIF(INDIRECT(sh&"!b:b"),D2,INDIRECT(sh&"!c:c"))))